يوضح هذا المقال كيفية استخدام أسلوب FileDialog الجديد في Microsoft Access لعرض مربع الحوار الملفات المضمّنة لتحديد ما ملفات المستخدم المحدد.

ملاحظة : يعمل " أسلوب FileDialog " فقط في الإصدار المباع الكامل من Microsoft Access. لا يعمل هذا الأسلوب في تطبيق Microsoft Access وقت التشغيل.

في الإصدارات السابقة من Microsoft Access " ، يمكنك عدم عرض مربع الحوار " ملف دون استخدام إما Microsoft Common مربع حوار ActiveX Control أو إجراء المكالمات إلى واجهة برمجة التطبيقات (API) لـ Windows.

في Microsoft Access 2002 الأسلوب FileDialog الذي يسمح لك عرض مربع الحوار الملفات المستخدمة من قبل Microsoft Access لتحديد ما إذا تم تحديد الملفات ما من قبل المستخدم. المجموعة SelectedItems الكائن FileDialog تتضمن مسارات الملفات المحددة من قبل المستخدم. باستخدام For... كل حلقة, يمكنك تعداد هذه المجموعة وعرض كل ملف. المثال التالي حلقات عبر مجموعة ItemsSelected ويعرض الملفات الموجودة في مربع قائمة.

تقدم Microsoft الأمثلة البرمجية التوضيح فقط، دون أي ضمان سواء يتم التعبير عنها أو. ذلك يتضمن لكنه ليس حكراً على الضمانات الضمنية الخاصة بالتسويق أو الملاءمة لغرض معين. تفترض هذه المقالة أنك مألوفة مع لغة البرمجة التي يتم شرحها مع أدوات التي يتم استخدامها لإنشاء لتصحيح الإجراءات. تساعد مهندسي الدعم في Microsoft شرح وظيفة إجراء محدد " ، ولكن فإنها لن يقوم بتعديل هذه الأمثلة لتقديم وظيفة أو إنشاء إجراءات تستوفي متطلبات محددة الخاص بك ".
افتح نموذج قاعدة البيانات Northwind.mdb.
إنشاء نموذج فارغ جديد في طريقة العرض " تصميم ".
إضافة عناصر التحكم التالية إلى النموذج:

Command button
--------------------------
Name: cmdFileDialog
Caption: Add Files
OnClick: [Event Procedure]

List box
-------------------------
Name: FileList
RowSourceType: Value List


من القائمة عرض انقر فوق " تعليمات برمجية لفتح وحدة نمطية للنموذج في محرر Visual Basic ".
من القائمة أدوات انقر فوق " المراجع ".
انقر لتحديد خانة الاختيار " مكتبة كائنات Microsoft Office 10.0 .
انقر فوق موافق لإغلاق مربع الحوار المراجع .
بإضافة التعليمة البرمجية التالية إلى الوحدة النمطية للنموذج:
Option Compare Database
Option Explicit

Private Sub cmdFileDialog_Click()

'Requires reference to Microsoft Office 10.0 Object Library.

Dim fDialog As Office.FileDialog
Dim varFile As Variant

'Clear listbox contents.
Me.FileList.RowSource = ""

'Set up the File Dialog.
Set fDialog = Application.FileDialog(msoFileDialogFilePicker)
With fDialog
'Allow user to make multiple selections in dialog box
.AllowMultiSelect = True

'Set the title of the dialog box.
.Title = "Please select one or more files"

'Clear out the current filters, and add our own.
.Filters.Clear
.Filters.Add "Access Databases", "*.MDB"
.Filters.Add "Access Projects", "*.ADP"
.Filters.Add "All Files", "*.*"

'Show the dialog box. If the .Show method returns True, the
'user picked at least one file. If the .Show method returns
'False, the user clicked Cancel.
If .Show = True Then
'Loop through each file selected and add it to our list box.
For Each varFile In .SelectedItems
Me.FileList.AddItem varFile
Next
Else
MsgBox "You clicked Cancel in the file dialog box."
End If
End With
End Sub

اتمنى منكم خالص الدعاء